Dateien in Tagesordner sammeln

Ich muss jeden Tag Dateien von Zip, CD und aus E-Mails zusammentragen. Diese lästige Arbeit möchte ich mir erleichtern: Ideal wäre ein täglich neu erstellter Ordner mit dem aktuellen Datum, in den ich Dateien via ‘Senden an’ übertragen kann.

Am einfachsten gelingt das mit einem kleinen WSH-Skript - das hier als Beispiel gezeigte Listing müssen Sie in einer Datei mit der Endung .vbs abspeichern. Es erzeugt einen Ordner mit dem aktuellen Datum als Name und legt eine Verknüpfung dorthin in Ihrem ‘Senden an’-Ordner an.

Damit das Skript täglich läuft, können Sie einfach eine Verknüpfung darauf in Ihrem Autostart-Ordner im Start-Menü anlegen. Falls Sie es gewohnt sind, den Rechner durchlaufen zu lassen, und sich deshalb nicht täglich neu anmelden, nehmen Sie das Skript stattdessen in den Ordner ‘Geplante Tasks’ in der Systemsteuerung auf und sorgen dafür, dass es täglich kurz nach Mitternacht läuft. (hos)

Ein kleines WSH-Skript ermöglicht bequeme Backups.

' Hier an eigene Bedürfnisse anpassen
basisOrdner = "\\MeinServer\Tagesbackups\"
LinkName = "\Backups von heute.lnk"

Set FS = CreateObject( "Scripting.FileSystemObject")
Set wShell = WScript.CreateObject( "WScript.Shell")
' Pfad des "Senden an"-Ordners
strSendTo = wShell.SpecialFolders("SendTo")
Today = Year(Now) & Right("0" & Month(Now), 2) & Right("0" & Day(Now), 2)

' Ordner für heute erstellen,
' falls noch nicht vorhanden
If not FS.FolderExists(basisOrdner & Today) Then
  FS.CreateFolder basisOrdner & Today
End If

' Ggf. SendTo-Link von gestern löschen
If FS.FileExists(strSendTo & LinkName) Then
  FS.DeleteFile strSendTo & LinkName
End If

' Neuen Shortcut erzeugen
Set Shortcut = wShell.CreateShortcut( strSendTo & LinkName)
Shortcut.TargetPath = basisOrdner & Today
Shortcut.Save


(hos)